| >!Run file for Flashback
|
Set Flashback$Dir <Obey$Dir>
Set Flashback$UnCrunch Yes
RMEnsure UnCrunch 0 Set Flashback$UnCrunch No
Set Flashback$Fix Patcher
RMEnsure ADFFS 2.28 Set Flashback$Fix ADFFS
RMEnsure ADFFS 2.04 Set Flashback$Fix Patcher
RMEnsure UtilityModule 3.70 RMEnsure CallASWI 0.02 RMLoad System:Modules.CallASWI
RMEnsure Patcher 0 RMLoad System:Modules.Patcher
RMEnsure Patcher 0 If "<Flashback$Fix>"="Patcher" Then Set Flashback$Fix No
SetEval Floppy 0
If "<Flashback$Dir>" = "ADFS::Flashback.$.!Flashback" Then SetEval Floppy -1
If Floppy Then Set Flashback$Dir ADFS::0.$.!Flashback
Set Alias$FBRun Run <Flashback$Dir>.r.%*0

| Change to VGA to avoid letterboxing
|
Set Rate TV

Set VDM <Rate>1
FBRun IfVidC20 Set VDM <Rate>20
If "<VDM>" = "VGA1" Then FBRun GameModes

| Path name for saved games
|
If Floppy     Then Set Flashback$Savedir ADFS::0.$
If NOT Floppy Then Set Flashback$Savedir <Flashback$Dir>.^

| Delete to keep system memory intact
|
FBRun ShrinkMem

IF "<Rate>" = "TV"  Then FBRun ScreenMem 168K
IF "<Rate>" = "VGA" Then FBRun ScreenMem 300K
IF "<Memory>" <> "All" Then FBRun AtLeast 720K ERROR Flashback needs at least 720K On a one megabyte machine please boot this disc with Ctrl-Shift-Break

Unset Floppy
Unset Memory
Unset FBRun
Unset Rate

| Add -gamerate -cinerate -keys here
|
If "<Flashback$Fix>"="Patcher" AND "<Flashback$UnCrunch>"="No" THEN RPCCacheFixOn
If "<Flashback$Fix>"<>"ADFFS" AND "<Flashback$UnCrunch>"="No" THEN cache off
If "<Flashback$Fix>"="ADFFS" AND "<Flashback$UnCrunch>"="No" THEN ADFCacheOff 500
Run <Flashback$Dir>.Flashback <VDM> Table1 Sound1
If "<Flashback$Fix>"="Patcher" AND "<Flashback$UnCrunch>"="No" THEN RPCCacheFixOff
If "<Flashback$Fix>"="No" AND "<Flashback$UnCrunch>"="No" THEN cache on